AC_INIT(libtranslate, 0.99, jylefort@brutele.be)
AC_CONFIG_SRCDIR(src/translate.h)

AC_PREREQ(2.59)

### command line arguments

TRANSLATE_ARG_ENABLE(generic, [do not build the generic module])
TRANSLATE_ARG_ENABLE(talkfilters, [do not build the talkfilters module])

TRANSLATE_ARG_COMPILE_WARNINGS
TRANSLATE_ARG_ENABLE(regression-tests, [build and run regression tests], no)

### initialization

AM_INIT_AUTOMAKE(foreign)
AM_MAINTAINER_MODE
AM_CONFIG_HEADER(config.h)
AC_PROG_LIBTOOL

### i18n

GETTEXT_PACKAGE=AC_PACKAGE_NAME
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Define to the gettext package name])
AC_SUBST(GETTEXT_PACKAGE)

ALL_LINGUAS="fr"
AM_GLIB_GNU_GETTEXT
AM_GLIB_DEFINE_LOCALEDIR(LOCALEDIR)

AC_PROG_INTLTOOL

### system features

AC_SYS_LARGEFILE

# check for ANSI C headers
AC_HEADER_STDC
if test $ac_cv_header_stdc != yes; then
	AC_MSG_ERROR([ANSI C headers not present])
fi

### mandatory libraries and programs

PKG_CHECK_MODULES(GLIB, [gobject-2.0 >= 2.4.0 gmodule-2.0 >= 2.4.0 gthread-2.0 >= 2.4.0],, [AC_MSG_ERROR([unable to find the GLib libraries])])

# not needed by end users
GTK_DOC_CHECK([1.0])

### optional libraries

if TRANSLATE_FEATURE_ENABLED(generic); then
	PKG_CHECK_MODULES(SOUP, [libsoup-2.2],, [TRANSLATE_FEATURE_DISABLE(generic, [libsoup not found])])
fi
if TRANSLATE_FEATURE_ENABLED(generic); then
	PKG_CHECK_MODULES(LIBXML, [libxml-2.0],, [TRANSLATE_FEATURE_DISABLE(generic, [libxml not found])])
fi

if TRANSLATE_FEATURE_ENABLED(talkfilters); then
	AM_PATH_TALKFILTERS(, [TRANSLATE_FEATURE_DISABLE(talkfilters, [GNU Talk Filters not found])])
fi

### Automake conditionals

AM_CONDITIONAL(WITH_GENERIC, [TRANSLATE_FEATURE_ENABLED(generic)])
AM_CONDITIONAL(WITH_TALKFILTERS, [TRANSLATE_FEATURE_ENABLED(talkfilters)])
AM_CONDITIONAL(WITH_REGRESSION_TESTS, [TRANSLATE_FEATURE_ENABLED(regression-tests)])

### output

AC_CONFIG_FILES(Makefile
		data/Makefile
		data/libtranslate.pc
		docs/Makefile
		docs/man/Makefile
		docs/man/version.xml
		docs/reference/Makefile
		docs/reference/version.xml
		m4/Makefile
		po/Makefile.in
		src/Makefile
		src/modules/Makefile)
AC_OUTPUT

### report

cat <<EOF

$PACKAGE $VERSION is ready to be built.
The following settings will be used:

Installation prefixes
TRANSLATE_REPORT_ARGS([prefix, exec-prefix])
Installation directories
TRANSLATE_REPORT_ARGS([bindir, datadir, libdir, includedir, mandir])
Features
TRANSLATE_REPORT_FEATURES([generic, talkfilters])
Type "make" to build $PACKAGE $VERSION.
EOF