AC_DEFUN([AC_PATH_LINUX],
[
AC_MSG_CHECKING([for Linux kernel source])
AC_ARG_WITH(linux,[  --with-linux=DIR        Linux kernel source is in DIR],,
with_linux=yes)
ac_path_linux=
ac_file_linux_version_h=
ac_file_linux_autoconf_h=
if test x$with_linux = xno; then
  have_linux=disabled
else
  ac_current_version=`uname -r`
  if test x$with_linux = xyes; then
    ac_dir_list="/lib/modules/$ac_current_version/build /usr/src/linux-$ac_current_version /usr/src/kernel-source-$ac_current_version /usr/src/linux"
  else
    ac_dir_list=$with_linux
  fi
  have_linux=no
  for ac_dir in $ac_dir_list; do
    if test x$ac_dir != x && test -f $ac_dir/Makefile && test -d $ac_dir/include/linux; then
      ac_path_linux=$ac_dir
      ac_file_linux_version_h=
      ac_file_linux_autoconf_h=
      if test -f $ac_dir/include/linux/version.h; then
        ac_file_linux_version_h=$ac_dir/include/linux/version.h
      fi
      if test -f $ac_dir/include/linux/autoconf.h; then
        ac_file_linux_autoconf_h=$ac_dir/include/linux/autoconf.h
      fi
      if test x$ac_file_linux_version_h != x && test x$ac_file_linux_autoconf_h != x; then
        have_linux=yes
	break
      fi
    fi
  done
fi
if test x$ac_path_linux != x; then
  AC_MSG_RESULT($ac_path_linux)
else
  AC_MSG_RESULT($have_linux)
fi
if test x$have_linux = xno; then
  if test x$ac_path_linux = x; then
    AC_MSG_ERROR([Cannot find the Linux kernel source directory.
Please use --with-linux=DIR to specify the kernel source directory.
Read the INSTALL file for more information.
])
  else
    AC_MSG_ERROR([Your Linux kernel source is not configured.
Please read the INSTALL file for more information.])
  fi
fi
])

AC_DEFUN([AC_SYS_LINUX_VERSION],
[
AC_MSG_CHECKING([Linux version])
ac_sys_linux_version=unknown
if test x$have_linux = xyes; then
  ac_current_version=`uname -r`
  ac_sys_linux_version=$ac_current_version
  if test -f $ac_file_linux_version_h; then
    ac_version_list=`sed -n 's/.*REL.*"\(.*\)"/\1/p' $ac_file_linux_version_h`
    for ac_sys_linux_version in $ac_version_list; do
      if test x$ac_sys_linux_version = x$ac_current_version; then
        break
      fi
    done
  fi
fi
AC_MSG_RESULT($ac_sys_linux_version)
])