dnl Process this file with autoconf to produce a configure script.
dnl Process with: aclocal; autoconf; automake

AC_INIT(src/mount.c)

AM_CONFIG_HEADER(config.h)

AM_INIT_AUTOMAKE(mountapp, 3.0)

dnl Checks for host/os name
dnl =======================
AC_CANONICAL_HOST

dnl Checks for programs.
AC_PROG_CC
AC_ISC_POSIX
AC_PROG_MAKE_SET
AC_PROG_RANLIB
AC_PROG_GCC_TRADITIONAL
AC_PROG_INSTALL
AC_PROG_LN_S

AC_PATH_PROG(MOUNT_CMD, mount)
AC_PATH_PROG(UMOUNT_CMD, umount)
AC_PATH_PROG(EJECT_CMD, eject)
AC_PATH_PROG(XMESSAGE, xmessage)

AC_SUBST(MOUNT_CMD)
AC_SUBST(UMOUNT_CMD)
AC_SUBST(EJECT_CMD)
AC_SUBST(XMESSAGE)

AC_DEFINE_UNQUOTED(MOUNT_CMD, "$MOUNT_CMD")
AC_DEFINE_UNQUOTED(UMOUNT_CMD, "$UMOUNT_CMD")
AC_DEFINE_UNQUOTED(EJECT_CMD, "$EJECT_CMD")
AC_DEFINE_UNQUOTED(XMESSAGE, "$XMESSAGE")

dnl Checks for libraries.

dnl Checks for header files.
AC_PATH_X
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS(unistd.h)

dnl ===========================================
dnl         Stuff that uses X
dnl ===========================================
AC_PATH_XTRA

dnl
dnl Specify paths to look for graphic format libraries
dnl ==================================================
AC_ARG_WITH(gfx-libs,
[  --with-gfx-libs         pass compiler flags to look for gfx libraries],
    [GFXLIBS="$withval" GFX_LIB_PATH=$withval],    [GFXLIBS="" GFX_LIB_PATH=""])

AC_ARG_WITH(gfx-incs,
[  --with-gfx-incs         pass compiler flags to look for gfx header files],
    [GFXFLAGS="$withval" GFX_INC_PATH=$withval],
    [GFXFLAGS="" GFX_INC_PATH=""])

XCFLAGS="$X_CFLAGS"
XLFLAGS="$X_LIBS"
XLIBS="$X_EXTRA_LIBS -lX11"

CFLAGS="${CFLAGS} $GFX_INC_PATH $GFX_LIB_PATH"
shape=yes
AC_CHECK_LIB(Xext, XShapeCombineMask, [XLIBS="-lXext $XLIBS"], shape=no, $XLFLAGS $XLIBS)

if test "$shape" = no; then
    echo "********** WARNING *************"
    echo "You need X server shape extensions in order to run mount.app,"
    echo "and they were not found on your system."
    read foo
fi

dnl XPM Support  <- If you disable XPM, mount.app will not compile.
dnl ===========
xpm=yes
AC_ARG_ENABLE(xpm,
[  --disable-xpm           disable use of XPM pixmaps through libXpm],
    xpm=$enableval, xpm=yes)

if test "$xpm" = yes; then
    AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
    [GFXFLAGS="$GFXFLAGS -DUSE_XPM" GFXLIBS="$GFXLIBS -lXpm"],,
    $GFX_INC_PATH $GFX_LIB_PATH $XLFLAGS $XLIBS)
    AC_CHECK_LIB(m, cos)
    AC_CHECK_LIB(z, gzread,GFXLIBS="$GFXLIBS -lz",,
    $GFX_INC_PATH $GFX_LIB_PATH $XLFLAGS $XLIBS)
    AC_CHECK_LIB(jpeg, jpeg_destroy_compress, GFXLIBS="-ljpeg $GFXLIBS",,
    $GFX_INC_PATH $GFX_LIB_PATH $XLFLAGS $XLIBS)
    AC_CHECK_LIB(tiff, TIFFGetVersion, GFXLIBS="-ltiff $GFXLIBS",
    AC_CHECK_LIB(tiff34, TIFFGetVersion, GFXLIBS="-ltiff34 $GFXLIBS",,
    $GFX_INC_PATH $GFX_LIB_PATH $XLFLAGS $XLIBS $GFXLIBS),
    $GFX_INC_PATH $GFX_LIB_PATH $XLFLAGS $XLIBS $GFXLIBS)
fi

dnl =====================================================
dnl        Check for libWINGs (replaces libPropList)
dnl =====================================================

AC_CHECK_LIB(WINGs, WMGetFromPLString,
    [LIBPL_LIBS=-lWINGs LIBPL_INC_PATH="" missing=no],
    [missing=yes])

if test "$missing" = yes; then
    echo "********** WARNING *************"
    echo "libWINGs is not installed in your system."
    echo "You need to build it before building mount.app (if you already"
    echo "did that, remove config.cache and rerun configure)."
    echo "Please read the INSTALL file for detailed instructions."
    read foo
fi

AC_SUBST(LIBPL_LIBS)
AC_SUBST(LIBPL_INC_PATH)

GTK_LIBS=`gtk-config --libs`
GTK_CFLAGS=`gtk-config --cflags`
AC_SUBST(GTK_LIBS)
AC_SUBST(GTK_CFLAGS)

if test "${prefix}" = "NONE"; then
	prefix=/usr/local
fi

if test "${exec_prefix}" = "NONE"; then
	exec_prefix=${prefix}
fi

mountsdir='${bindir}'
pixmapdir='${datadir}/mount.app'
AC_SUBST(mountsdir)
AC_SUBST(pixmapdir)

if test "${bindir}" = '${exec_prefix}/bin'; then
	if test "${exec_prefix}" = '${prefix}'; then
		BINDIR=${prefix}/bin
	else
		BINDIR=${exec_prefix}/bin
	fi
else
	BINDIR=${bindir}
fi
AC_DEFINE_UNQUOTED(BINDIR, "$BINDIR")

if test "${datadir}" = '${prefix}/share'; then
	ICONDIR=${prefix}/share/mount.app
else
	ICONDIR=${datadir}/mount.app
fi
AC_DEFINE_UNQUOTED(ICONDIR, "$ICONDIR")

AC_SUBST(XLIBS)
AC_SUBST(XCFLAGS)
AC_SUBST(XLFLAGS)
AC_SUBST(GFXFLAGS)
AC_SUBST(GFXLIBS)

dnl Checks for typedefs, structures, and compiler characteristics.

dnl Checks for library functions.
AC_TYPE_SIGNAL
AC_CHECK_FUNCS(strdup strstr)

AC_OUTPUT(Makefile src/Makefile src/EXTRAS/Makefile)