dnl
dnl File:        configure.in
dnl Revision:    $Id: configure.in,v 1.6 2001/11/05 21:50:41 rkowen Exp $
dnl Created:     94/06/18
dnl Author:      Leif Hedstrom<hedstrom@inf.ethz.ch>
dnl		 Martin S. Utesch <wstd@hl.siemens.de>
dnl 		 Peter W. Osel <pwo@GUUG.DE>
dnl
dnl Process this file with autoconf to produce a configure script
dnl You need autoconf 2.4 or better!
dnl
dnl --------------------------------------------------------------
AC_INIT(version.c)
AC_CONFIG_HEADER(config.h)
AC_PREREQ(2.4)
dnl --------------------------------------------------------------
dnl
dnl Some special substitution we need:
dnl
dnl X11_INC_DIR		To find the X11 include files
dnl X11_LIB_DIR		To find the X11 library files
dnl X11_LIBS		The X11 libararies we need
dnl TCL_MINOR_VERSION	The installed TCL version
dnl TCL_MAJOR_VERSION	The installed TCL version
dnl TCL_VERSION		The installed TCL version (major.minor)
dnl TCL_INC_DIR		To find the TCL include files
dnl TCL_LIB_DIR		To find the TCL library file
dnl TCLX_INC_DIR	To find the TCLX include files
dnl TCLX_LIB_DIR	To find the TCLX library file
dnl TCLX_LIBS		The TCLX libararies we need
dnl STATIC		Link the binary 'static'
dnl WITH_LOGGING	Whether syslogging is enabled
dnl MODULEPATH		The modulepath we want
dnl VERSIONPATH		The modulepath different versions of modules
dnl AUTOLOADPATH	directories where Tcl will search for libraries to load
dnl ETCPATH		Where to find the /etc/"login" files
dnl SKELPATH		Where to find the $HOME/dot file skeletons
dnl DATE		Module package date
dnl VERSION		Module package version
dnl THISDIR		Full path to this source directory
dnl R_OPTION
dnl
AC_SUBST(X11_INC_DIR)dnl
AC_SUBST(X11_LIB_DIR)dnl
AC_SUBST(X11_LIBS)dnl
AC_SUBST(TCL_INC_DIR)dnl
AC_SUBST(TCL_LIB_DIR)dnl
AC_SUBST(TCL_VERSION)dnl
AC_SUBST(TCLX_INC_DIR)dnl
AC_SUBST(TCLX_LIB_DIR)dnl
AC_SUBST(TCLX_LIBS)dnl
AC_SUBST(STATIC)dnl
AC_SUBST(WITH_LOGGING)dnl
AC_SUBST(MODULEPATH)dnl
AC_SUBST(VERSIONPATH)dnl
AC_SUBST(AUTOLOADPATH)dnl
AC_SUBST(ETCPATH)dnl
AC_SUBST(SKELPATH)dnl
AC_SUBST(DOT_EXT)dnl
AC_SUBST(VERSION)dnl
AC_SUBST(R_OPTION)dnl
AC_SUBST(DATE)dnl
AC_SUBST(THISDIR)dnl
dnl
dnl --------------------------------------------------------------
dnl Get Modules version & date
VERSION='(unknown)'
VERSION=`sed -n -e 's/^.*version_string.*"\(.*\)";$/\1/p' ${srcdir}/version.c`
AC_MSG_RESULT([VERSION = $VERSION])
DATE='(DDMmmYYYY)'
DATE=`sed -n -e 's/^.*date_string.*"\(.*\)";$/\1/p' ${srcdir}/version.c`
AC_MSG_RESULT([DATE = $DATE])
echo "configuring for Modules $VERSION		$DATE"
dnl --------------------------------------------------------------
THISDIR=`pwd`
AC_MSG_RESULT([THISDIR = $THISDIR])
dnl --------------------------------------------------------------
dnl compute a default path ... strip off @VERSION@ if present in prefix
dnl also expand @VERSION@ in path
DEFAULTPATH=default
if test "$prefix" != "NONE" ; then
  DEFAULTPATH=`echo $prefix | sed -e s%@VERSION@%$DEFAULTPATH%g`
  BASEPREFIX=`echo $prefix | sed -e s%@VERSION@%%g`
  prefix=`echo $prefix | sed -e s%@VERSION@%$VERSION%g`
  NODEFAULTPATH=$prefix
  export prefix
else
  DEFAULTPATH=`echo $ac_default_prefix | sed -e s%@VERSION@%$DEFAULTPATH%g`
  BASEPREFIX=`echo $ac_default_prefix | sed -e s%@VERSION@%%g`
  ac_default_prefix=`echo $ac_default_prefix | sed -e s%@VERSION@%$VERSION%g`
  NODEFAULTPATH=$ac_default_prefix
  export prefix
fi
AC_MSG_RESULT([DEFAULTPATH = $DEFAULTPATH])
AC_MSG_RESULT([BASEPREFIX = $BASEPREFIX])
AC_SUBST(DEFAULTPATH)
AC_SUBST(BASEPREFIX)
export DEFAULTPATH
export NODEFAULTPATH
export BASEPREFIX
dnl --------------------------------------------------------------
dnl Some standard autoconfig stuff
dnl Checks for programs
dnl
AC_AIX
AC_ISC_POSIX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_GCC_TRADITIONAL
AC_PROG_INSTALL
AC_SET_MAKE
AC_PROGRAM_PATH(UNAME, uname, "")
AC_HEADER_DIRENT
AC_STDC_HEADERS
AC_HAVE_HEADERS(string.h memory.h stdlib.h unistd.h termio.h fcntl.h ctype.h \
	stdarg.h varargs.h syslog.h)
AC_HAVE_HEADERS(errno.h sys/ioctl.h sys/termios.h sys/mode.h sys/stat.h      \
	sys/param.h)
AC_SIZE_T
AC_CONST
AC_FIND_X 
dnl --------------------------------------------------------------
dnl Checks for header files
dnl Solaris 2.x: This requires -lnsl and -lsocket. If AC_PATH_XTRA
dnl              did not search for these, search them explicitely.
dnl              MUST be done BEFORE AC_PATH_XTRA!
AC_CHECK_LIB(socket, socket)
AC_CHECK_LIB(nsl, t_accept)
AC_PATH_XTRA 
AC_HAVE_FUNCS(strdup strtok uname gethostname getdomainname tempnam tmpnam \
	syslog dup2)
AC_PATH_PROG_SEARCH(_CPPSTDIN, cpp, /lib /usr/lib /usr/lang \
	/usr/local/lang /usr/ccs/lib, [${CC} -E])
AC_DEFINE_UNQUOTED(CPPSTDIN, "$_CPPSTDIN")
AC_PROGRAM_PATH(_PHOST, hostname, "")
test "$_PHOST" != ""  && AC_DEFINE_UNQUOTED(PHOSTNAME, "$_PHOST")
AC_PATH_PROG(RUNTEST, runtest, "./not_installed")
test "$RUNTEST" = "" && echo "Install DEJAGNU and rerun configure if you \
want to run the testsuite"
dnl
dnl Here we define some --with & --enable things:
dnl
dnl --with-force-path=<path>	With force path=<path>
dnl --without-force-path	Without  - " -		[DEF]
dnl
dnl --with-split-size[=<size>]	With split size=<size>
dnl --without-split-size	Without  - " -		[DEF]
dnl
dnl --with-static[=<option>]	With static linking
dnl --without-static		Without  - " -		[DEF]
dnl
dnl --enable-cache		With directory cache	[DEF]
dnl --disable-cache		Without  - " -
dnl
dnl --enable-shell-funcs	With sh functions	[DEF]
dnl --disable-shell-funcs	Without  - " -
dnl
dnl --enable-shell-eval		With shell alias eval
dnl --disable-shell-eval	Without  - " -		[DEF]
dnl
dnl --enable-free		With free() calls
dnl --disable-free		Without  - " -		[DEF]
dnl
dnl --with-debug[=<option>]	Set up debugging level
dnl --without-debug		Without  - " -		[DEF]
dnl
dnl --enable-version-magic      Set .version magic requirement [DEF]
dnl --disable-version-magic     .version need not have magic cookie
dnl
dnl --enable-use-default        Use PREFIX - VERSION in init scripts [DEF]
dnl --disable-use-default       Use PREFIX in init scripts
dnl
if test "$no_x" != "yes"; then
	AC_DEFINE(HAS_X11LIBS)
	AC_MAKE_INCLUDE(x_includes, X11_INC_DIR)
	AC_MAKE_LIBRARY(x_libraries, X11_LIB_DIR)
	X11_LIBS="-lXmu -lXt -lX11"
	AC_CHECKING(for -lXext)
	test -f "$x_libraries/libXext.a" && X11_LIBS="$X11_LIBS -lXext"
fi
AC_ARG_WITH(force-path,
	[  --with-force-path=<path>    use force path=<path>         [no]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="/usr/bin"
		AC_DEFINE_UNQUOTED(FORCE_PATH, "$withval")
	fi)
AC_ARG_WITH(split-size,
	[  --with-split-size[=<size>]  use split size=<size>         [no]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval=900
		AC_DEFINE_UNQUOTED(LMSPLIT_SIZE, ${withval})
	fi)
AC_ARG_WITH(static,
	[  --with-static[=<option>]    use static linking            [no]],
	AC_SET_STATIC(STATIC, $withval))
AC_ARG_ENABLE(cache,
	[  --enable-cache              use directory cache           [yes]],
	if test "$enableval" = "yes"; then
	    AC_DEFINE(CACHE_AVAIL)
	fi,
	AC_DEFINE(CACHE_AVAIL))
AC_ARG_ENABLE(shell-funcs,
	[  --enable-shell-funcs        use sh functions              [yes]],
	if test "$enableval" = "yes"; then
	    AC_DEFINE(HAS_BOURNE_FUNCS)
	fi, AC_DEFINE(HAS_BOURNE_FUNCS))
AC_ARG_ENABLE(shell-eval,
	[  --enable-shell-eval         use shell alias eval          [no]],
	if test "$enableval" = "yes"; then
	    AC_DEFINE(EVAL_ALIAS)
	fi)
AC_ARG_ENABLE(free,
	[  --enable-free               use free() calls              [no]],
	if test "$enableval" = "yes"; then
	    AC_DEFINE(USE_FREE)
	fi)
AC_ARG_WITH(cache-umask,
	[  --with-cache-umask=<umask>  use cache files umask=<umask> [000]],
	if test "$withval" != "no"; then
	    test "$withval" = "yes" && withval=0
	    AC_DEFINE_UNQUOTED(CACHE_UMASK, ${withval})
	fi)
AC_ARG_WITH(debug,
	[  --with-debug=<value>        set debugging level <value>   [no]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="1"
		AC_DEFINE_UNQUOTED(WITH_DEBUG_INFO, ${withval})
	fi)
AC_ARG_ENABLE(version-magic,
	[  --enable-version-magic      set .version magic requirement[yes]],
	if test "$enableval" != "no"; then
		AC_DEFINE(VERSION_MAGIC,1)
	else
		AC_DEFINE(VERSION_MAGIC,0)
	fi, AC_DEFINE(VERSION_MAGIC,1))
AC_ARG_ENABLE(use-default,
	[  --enable-use-default        use DEFAULTPATH in init scripts [DEF]],
	if test "$enableval" = "no"; then
		DEFAULTPATH=$NODEFAULTPATH
		AC_SUBST(DEFAULTPATH)
	fi)
dnl --------------------------------------------------------------
dnl
dnl  Logging
dnl  The following option allow switching logging on and off
dnl  and provide a possibility to set up the default facilities
dnl
WITH_LOGGING=0
AC_ARG_ENABLE(logging,
	[  --enable-logging            turn logging on		     [no]],
	if test "$enableval" = "yes"; then
		AC_DEFINE(WITH_LOGGING)
		WITH_LOGGING=1
	fi)
AC_ARG_WITH(log-dir,
	[  --with-log-dir=<value>      select an alternate log dir.  [no]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="/tmp"
		AC_DEFINE_UNQUOTED(WITH_LOG_DIR, "$withval")
	fi)
AC_ARG_WITH(log-facility-verbose,
	[  --with-log-facility-verbose[=<facility>]  Log facility    [stderr]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="stderr"
		AC_DEFINE_UNQUOTED(WITH_LOG_FACILITY_VERBOSE, "$withval")
	fi)
AC_ARG_WITH(log-facility-info,
	[  --with-log-facility-info[=<facility>]     Log facility    [stderr]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="local7.notice"
		AC_DEFINE_UNQUOTED(WITH_LOG_FACILITY_INFO, "$withval")
	fi)
AC_ARG_WITH(log-facility-debug,
	[  --with-log-facility-debug[=<facility>]    Log facility    [no]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="local7.notice"
		AC_DEFINE_UNQUOTED(WITH_LOG_FACILITY_DEBUG, "$withval")
	fi)
AC_ARG_WITH(log-facility-trace,
	[  --with-log-facility-trace[=<facility>]    Log facility    [no]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="local7.notice"
		AC_DEFINE_UNQUOTED(WITH_LOG_FACILITY_TRACE, "$withval")
	fi)
AC_ARG_WITH(log-facility-warn,
	[  --with-log-facility-warn[=<facility>]     Log facility    [stderr]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="local7.warning"
		AC_DEFINE_UNQUOTED(WITH_LOG_FACILITY_WARN, "$withval")
	fi)
AC_ARG_WITH(log-facility-problem,
	[  --with-log-facility-problem[=<facility>]  Log facility    [stderr]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="local7.error"
		AC_DEFINE_UNQUOTED(WITH_LOG_FACILITY_PROB, "$withval")
	fi)
AC_ARG_WITH(log-facility-error,
	[  --with-log-facility-error[=<facility>]    Log facility    [stderr]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="local7.error"
		AC_DEFINE_UNQUOTED(WITH_LOG_FACILITY_ERROR, "$withval")
	fi)
AC_ARG_WITH(log-facility-fatal,
	[  --with-log-facility-fatal[=<facility>]    Log facility    [stderr]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="local7.error"
		AC_DEFINE_UNQUOTED(WITH_LOG_FACILITY_FATAL, "$withval")
	fi)
AC_ARG_WITH(log-facility-panic,
	[  --with-log-facility-panic[=<facility>]    Log facility    [stderr]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval="local7.error"
		AC_DEFINE_UNQUOTED(WITH_LOG_FACILITY_PANIC, "$withval")
	fi)
dnl --------------------------------------------------------------
dnl
dnl  Tracing
dnl  The following option allow switching tracing on and off on a
dnl  per module command basis
dnl
AC_ARG_WITH(trace-load,
	[  --with-trace-load=<value>   specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_LOAD, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_LOAD, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-unload,
	[  --with-trace-unload=<value> specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_UNLOAD, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_UNLOAD, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-switch,
	[  --with-trace-switch=<value> specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_SWITCH, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_SWITCH, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-disp,
	[  --with-trace-disp=<value>   specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_DISP, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_DISP, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-list,
	[  --with-trace-list=<value>   specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_LIST, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_LIST, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-avail,
	[  --with-trace-avail=<value>  specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_AVAIL, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_AVAIL, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-help,
	[  --with-trace-help=<value>   specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_HELP, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_HELP, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-init,
	[  --with-trace-init=<value>   specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_INIT, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_INIT, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-use,
	[  --with-trace-use=<value>    specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_USE, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_USE, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-unuse,
	[  --with-trace-unuse=<value>  specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_UNUSE, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_UNUSE, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-update,
	[  --with-trace-update=<value> specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_UPDATE, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_UPDATE, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-purge,
	[  --with-trace-purge=<value>  specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_PURGE, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_PURGE, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-clear,
	[  --with-trace-clear=<value>  specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_CLEAR, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_CLEAR, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-whatis,
	[  --with-trace-whatis=<value> specify a pattern for trace   [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_WHATIS, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_WHATIS, "$withval")
		fi
	fi)
AC_ARG_WITH(trace-apropos,
	[  --with-trace-apropos=<value> specify a pattern for trace  [no]],
	if test "$withval" != "no"; then
		if test "$withval" = "yes"; then
			AC_DEFINE_UNQUOTED(WITH_TRACE_APROPOS, _all_on)
		else
			AC_DEFINE_UNQUOTED(WITH_TRACE_APROPOS, "$withval")
		fi
	fi)
dnl --------------------------------------------------------------
dnl
dnl Find libraries, functions and special programs
dnl	The dynamic loader library should only be probed for, if
dnl	static linking is not switched on!
dnl
AC_CHECK_LIB(m, log)
if test "${STATIC-foobar}" = "foobar"; then
    AC_CHECK_LIB(dl, dlopen)
fi
dnl
dnl --------------------------------------------------------------
dnl
dnl Locate TCL libraries and include files
dnl
dnl --with-tcl-include=<path>	With TCL include path=<path>
dnl --without-tcl-include	Seek for default include path
dnl
dnl --with-tcl-libraries=<path>	With TCL lib path=<path>
dnl --without-tcl-libraries	Seek for default lib path
dnl
dnl --with-tcl-version=<vers>  	With TCL version=<version
dnl --without-tcl-version	Seek for the TCL version
dnl
AC_FIND_TCL
AC_MAKE_INCLUDE(tcl_includes, TCL_INC_DIR)
AC_MAKE_LIBRARY(tcl_libraries, TCL_LIB_DIR)
dnl the TCL versions are defined in the tcl.h
dnl AC_DEFINE_UNQUOTED(TCL_MINOR_VERSION, `echo $tcl_version | sed 's/^.*\.//'`)
dnl AC_DEFINE_UNQUOTED(TCL_MAJOR_VERSION, `echo $tcl_version | sed 's/\..*$//'`)
TCL_VERSION=$tcl_version
dnl
dnl --------------------------------------------------------------
dnl search for tclx after tcl, not before to benefit from tcl_includes and
dnl tcl_libraries;
dnl
dnl --with-tclx			With extended TCL
dnl --without-tclx		Without  - " -		[DEF]
dnl
dnl --with-tclx-include=<path>	With ext. TCL include path=<path>
dnl --without-tclx-include	Seek for default include path
dnl
dnl --with-tclx-libraries=<path>With ext. TCL lib path=<path>
dnl --without-tclx-libraries	Seek for default lib path
dnl
AC_ARG_WITH(tclx,
	[  --with-tclx                 use Extended TCL              [no]],
	if test "$withval" != "no"; then
		AC_DEFINE(HAS_TCLXLIBS)
		AC_FIND_TCLX
		AC_MAKE_INCLUDE(tclx_includes, TCLX_INC_DIR)
		AC_MAKE_LIBRARY(tclx_libraries, TCLX_LIB_DIR)
		TCLX_LIBS="-ltclx"
		AC_REQUIRE([AC_PATH_XTRA])
	fi)
dnl
dnl --------------------------------------------------------------
dnl
dnl   --with-module-path
dnl   --with-version-path
dnl   --with-autoload-path
dnl   --with-etc-path
dnl   --with-skel-path
dnl
AC_ARG_WITH(module-path,
	[  --with-module-path=<path>   use module path=<path>        [/usr/local/Modules/modulefiles]],
	MODULEPATH="$withval"
	AC_MSG_RESULT([MODULEPATH = $with_module_path])
	AC_DEFINE_UNQUOTED(MODULEPATH, "$withval")
	,
	AC_MSG_WARN([if using '--with-module-path': need to specify a path!])
	if test "$withval" = "no" || test "$withval" = "yes"; then
		withval="/usr/local/Modules/modulefiles"
	fi
	AC_MSG_WARN([will use MODULEPATH=$withval])
	MODULEPATH="$withval"
	AC_DEFINE_UNQUOTED(MODULEPATH, "$withval"))
AC_ARG_WITH(version-path,
	[  --with-version-path=<path>  use module path=<path>        [/usr/local/Modules/versions]],
	VERSIONPATH="$withval"
	AC_MSG_RESULT([VERSIONPATH = $with_version_path])
	AC_DEFINE_UNQUOTED(VERSIONPATH, "$withval")
	,
	AC_MSG_WARN([if using '--with-version-path': need to specify a path!])
	if test "$withval" = "no" || test "$withval" = "yes"; then
		withval="$prefix/Modules/versions"
	fi
	AC_MSG_WARN([will use VERSIONPATH=$withval])
	VERSIONPATH="$withval"
	AC_DEFINE_UNQUOTED(VERSIONPATH, "$withval"))
AC_ARG_WITH(autoload-path,
	[  --with-autoload-path=<path> use autoload path=<path>      [$ac_default_prefix/lib/tcl]],
	if test "$withval" = "no" || test "$withval" = "yes"; then
		if test "$prefix" != "NONE" ; then
			withval="$prefix/lib/tcl"
		else
			withval="$ac_default_prefix/lib/tcl"
		fi
	fi
	AUTOLOADPATH="$withval"
	AC_DEFINE_UNQUOTED(AUTOLOADPATH, "$withval"))
AC_ARG_WITH(etc-path,
	[  --with-etc-path=<path>      use etc path=<path>           [/etc]],
	if test "$withval" = "no" || test "$withval" = "yes"; then
	AC_MSG_WARN([if using '--with-etc-path': need to specify a path! Using /etc])
		withval="/etc"
	fi
	ETCPATH="$withval"
	,
	ETCPATH="/etc")
AC_ARG_WITH(skel-path,
	[  --with-skel-path=<path>     use skel path=<path>          [/etc/skel]],
	if test "$withval" = "no" || test "$withval" = "yes"; then
	AC_MSG_WARN([if using '--with-skel-path': need to specify a path! Using /etc/skel])
		withval="/etc/skel"
	fi
	SKELPATH="$withval"
	,
	SKELPATH="/etc/skel")
AC_ARG_WITH(dot-ext,
	[  --with-dot-ext[=<.ext>]     append <.ext> to shell init   [.ext]],
	if test "$withval" != "no"; then
		test "$withval" = "yes" && withval=".ext"
		AC_DEFINE_UNQUOTED(DOT_EXT, "$withval")
	else
		AC_DEFINE_UNQUOTED(DOT_EXT, "")
	fi)
dnl
dnl --------------------------------------------------------------
dnl Now put it all out!
dnl
AC_OUTPUT(Makefile modules.lsm .spec doc/Makefile init/Makefile
	init/bash init/csh init/ksh init/perl init/python init/sh init/tcsh
	init/zsh init/.modulespath
	doc/module.1 doc/modulefile.4
	etc/Makefile etc/add.modules etc/mkroot
	etc/skel/.cshrc etc/skel/.login 
	etc/skel/.kshenv etc/skel/.profile 
	etc/global/csh.cshrc etc/global/csh.login etc/global/csh.modules
	etc/global/bashrc etc/global/profile etc/global/profile.modules
	ext/Makefile ext/add.ext
	ext/common/.cshrc ext/common/.login 
	ext/common/.kshenv ext/common/.profile 
	modulefiles/Makefile modulefiles/modules
	modulefiles/module-cvs modulefiles/module-info modulefiles/null
	modulefiles/use.own modulefiles/dot modulefiles/version
	testsuite/modulefiles/use/1.0 testsuite/modulefiles/use/2.0
	testsuite/modulefiles/use/2.1 testsuite/modulefiles/use/2.2
	testsuite/modules.00-init/015-version.exp
	testsuite/modules.50-cmds/100-loglevel.exp
	, date > stamp-h)dnl