dnl Copyright (C) 2003-2007 by Carnegie Mellon University.
dnl
dnl @OPENSOURCE_HEADER_START@
dnl 
dnl Use of the SILK system and related source code is subject to the terms 
dnl of the following licenses:
dnl 
dnl GNU Public License (GPL) Rights pursuant to Version 2, June 1991
dnl Government Purpose License Rights (GPLR) pursuant to DFARS 252.225-7013
dnl 
dnl NO WARRANTY
dnl 
dnl ANY INFORMATION, MATERIALS, SERVICES, INTELLECTUAL PROPERTY OR OTHER 
dnl PROPERTY OR RIGHTS GRANTED OR PROVIDED BY CARNEGIE MELLON UNIVERSITY 
dnl PURSUANT TO THIS LICENSE (HEREINAFTER THE "DELIVERABLES") ARE ON AN 
dnl "AS-IS" BASIS. CARNEGIE MELLON UNIVERSITY MAKES NO WARRANTIES OF ANY 
dnl KIND, EITHER EXPRESS OR IMPLIED AS TO ANY MATTER INCLUDING, BUT NOT 
dnl LIMITED TO, WARRANTY OF FITNESS FOR A PARTICULAR PURPOSE, 
dnl MERCHANTABILITY, INFORMATIONAL CONTENT, NONINFRINGEMENT, OR ERROR-FREE 
dnl OPERATION. CARNEGIE MELLON UNIVERSITY SHALL NOT BE LIABLE FOR INDIRECT, 
dnl SPECIAL OR CONSEQUENTIAL DAMAGES, SUCH AS LOSS OF PROFITS OR INABILITY 
dnl TO USE SAID INTELLECTUAL PROPERTY, UNDER THIS LICENSE, REGARDLESS OF 
dnl WHETHER SUCH PARTY WAS AWARE OF THE POSSIBILITY OF SUCH DAMAGES. 
dnl LICENSEE AGREES THAT IT WILL NOT MAKE ANY WARRANTY ON BEHALF OF 
dnl CARNEGIE MELLON UNIVERSITY, EXPRESS OR IMPLIED, TO ANY PERSON 
dnl CONCERNING THE APPLICATION OF OR THE RESULTS TO BE OBTAINED WITH THE 
dnl DELIVERABLES UNDER THIS LICENSE.
dnl 
dnl Licensee hereby agrees to defend, indemnify, and hold harmless Carnegie 
dnl Mellon University, its trustees, officers, employees, and agents from 
dnl all claims or demands made against them (and any related losses, 
dnl expenses, or attorney's fees) arising out of, or relating to Licensee's 
dnl and/or its sub licensees' negligent use or willful misuse of or 
dnl negligent conduct or willful misconduct regarding the Software, 
dnl facilities, or other rights or assistance granted by Carnegie Mellon 
dnl University under this License, including, but not limited to, any 
dnl claims of product liability, personal injury, death, damage to 
dnl property, or violation of any laws or regulations.
dnl 
dnl Carnegie Mellon University Software Engineering Institute authored 
dnl documents are sponsored by the U.S. Department of Defense under 
dnl Contract F19628-00-C-0003. Carnegie Mellon University retains 
dnl copyrights in all material produced under this contract. The U.S. 
dnl Government retains a non-exclusive, royalty-free license to publish or 
dnl reproduce these documents, or allow others to do so, for U.S. 
dnl Government purposes only pursuant to the copyright license under the 
dnl contract clause at 252.227.7013.
dnl 
dnl @OPENSOURCE_HEADER_END@

dnl RCSIDENT("$SiLK: configure.ac 8846 2007-09-06 17:46:01Z mthomas $")

AC_INIT([SiLK],[0.11.7],[silk-help@cert.org],[silk])
AC_PREREQ(2.59)
AC_COPYRIGHT([Copyright (C) 2001-2007 by Carnegie Mellon University
GNU Public License (GPL) Rights pursuant to Version 2, June 1991
Government Purpose License Rights (GPLR) pursuant to DFARS 252.225-7013])
AC_REVISION($SiLK: configure.ac 8846 2007-09-06 17:46:01Z mthomas $)
AC_CONFIG_SRCDIR([src/include/silk.h])
AC_CONFIG_AUX_DIR([autoconf])
AM_INIT_AUTOMAKE([1.6.3 foreign])
AM_CONFIG_HEADER([src/include/silk_config.h])

# Disable the horribly annoying automatic rebuild of configure, Makefile.in, &c
AM_MAINTAINER_MODE

# Initialize our stuff
SILK_AC_INIT

# These required before libtool
AC_LANG(C)
AC_AIX
AC_GNU_SOURCE

AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL

# Compiler
SILK_AC_COMPILER

# Verify that the site files exist
SILK_AC_OPT_SILK_SITE

# Checks for programs.
AC_PROG_AWK
AC_PROG_EGREP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_CHECK_PROGS(AR,ar)
dnl AC_CHECK_PROGS(BZIP,bzip2)
AC_CHECK_PROGS(CP,cp)
AC_CHECK_PROGS(FIND,find)
AC_CHECK_PROGS(GZIP,gzip)
dnl AC_CHECK_PROGS(LDCONFIG,ldconfig)
AC_CHECK_PROGS(LN,ln)
# Set MAILX here; use MAILX to #define SK_MAILER in SILK_AC_STD_SUBSTS()
AC_PATH_PROGS(MAILX,mailx Mail mail,,[$PATH:/bin:/usr/bin:/usr/local/bin])
AC_CHECK_PROGS(LD,ld)
AC_CHECK_PROGS(MAKEDEPEND,makedepend)
dnl AC_CHECK_PROGS(MD5,md5 md5sum)
AC_CHECK_PROGS(MKDIR,mkdir)
AC_CHECK_PROGS(MV,mv)
AC_CHECK_PROGS(PERL,perl)
AC_CHECK_PROGS(POD2HTML,pod2html)
AC_CHECK_PROGS(POD2MAN,pod2man)
AC_CHECK_PROGS(PODSELECT,podselect)
# if pod2man is not found, do not build the man pages
if test "X$POD2MAN" = "X"
then
    DEFAULT_DO_MAN_PAGES=
else
    DEFAULT_DO_MAN_PAGES=man-pages
fi
AC_SUBST(DEFAULT_DO_MAN_PAGES)

AC_CHECK_PROGS(PYTHON,python)
dnl AC_CHECK_PROGS(RATS,rats)
AC_CHECK_PROGS(RM,rm)
AC_CHECK_PROGS(SED,sed)
AC_CHECK_PROGS(SPLINT,splint)
AC_CHECK_PROGS(TAR,tar)
AC_CHECK_PROGS(TEST,test)
AC_CHECK_PROGS(TOUCH,touch)
AC_CHECK_PROGS(TR,tr)
AC_CHECK_PROGS(UNAME,uname)

# checks for lex and yacc
AM_PROG_LEX
AC_PROG_YACC


# Checks for libraries.
AC_SEARCH_LIBS([sqrt], [m])
AC_SEARCH_LIBS([dlopen], [dl])
AC_SEARCH_LIBS([nanosleep], [rt])
AC_SEARCH_LIBS([inet_ntoa], [nsl])
AC_SEARCH_LIBS([socket], [socket])
# Checks for library functions.
AC_CHECK_FUNCS([getopt_long_only imaxdiv inet_pton memccpy timegm socketpair statvfs])


# HEADER CHECKS

# header existence
AC_HEADER_DIRENT
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_HEADER_TIME
dnl AC_HEADER_STAT
dnl AC_HEADER_STDBOOL
AC_CHECK_HEADERS([assert.h arpa/inet.h ctype.h errno.h fcntl.h glob.h inttypes.h limits.h locale.h malloc.h math.h memory.h netdb.h netinet/in.h netinet/tcp.h pthread.h regex.h signal.h stdarg.h stddef.h stdint.h stdlib.h string.h strings.h sys/mman.h sys/msg.h sys/resource.h sys/select.h sys/socket.h sys/statvfs.h sys/time.h sys/uio.h sys/wait.h unistd.h])


# Checks for typedefs and structures, and compiler characteristics.
AC_C_BIGENDIAN
AC_SYS_LARGEFILE
AC_TYPE_MODE_T
AC_TYPE_OFF_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_FUNC_FSEEKO
dnl AC_STRUCT_ST_BLOCKS
dnl AC_STRUCT_TM
AC_CHECK_TYPES([long, unsigned long long, intmax_t, imaxdiv_t])
AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF([unsigned long long])
if test "$ac_cv_sizeof_long" = 8 -o "$ac_cv_sizeof_unsigned_long_long" = 8 ;
then
    :
else
    AC_MSG_ERROR([${PACKAGE} needs a 64bit integer type])
fi


SILK_AC_CHECK_VARIOUS_DECLS
SILK_AC_NEED_REENTRANT
SILK_AC_PTHREAD_LDFLAGS
SILK_AC_OPT_WITH_ZLIB
SILK_AC_OPT_WITH_LZO
SILK_AC_OPT_WITH_PCAP

m4_ifdef([PKG_CHECK_MODULES], [SILK_AC_OPT_WITH_GNUTLS])
m4_ifdef([PKG_CHECK_MODULES], [SILK_AC_OPT_WITH_FIXBUF])
m4_ifdef([PKG_CHECK_MODULES], [SILK_AC_OPT_WITH_IPA])
#m4_ifdef([PKG_CHECK_MODULES], [SILK_AC_OPT_WITH_PCRE])


SILK_AC_OPT_ENABLE_LOCALTIME
SILK_AC_OPT_ENABLE_LEGACY_TIMESTAMP
SILK_AC_OPT_ENABLE_INITIAL_TCPFLAGS
SILK_AC_OPT_DISABLE_ANALYSIS_TOOLS
SILK_AC_OPT_DISABLE_PACKING_TOOLS
SILK_AC_OPT_ENABLE_OUTPUT_COMPRESSION
SILK_AC_OPT_DATA_ROOTDIR


# Look for special #defines that we want on the compile line
SILK_AC_COMP_INCLUDE_TO_CFLAG

# Prepare final output
SILK_AC_STD_SUBSTS
SILK_AC_FIND_SOURCE_MAKEFILES

# Generate output
AC_CONFIG_FILES([
                 Makefile
                 src/Makefile
                 src/include/Makefile
                 site/Makefile
                 site/generic/Makefile
                 site/twoway/Makefile
                ])
AC_OUTPUT

SILK_AC_PRINT_SUMMARY