# Extra functions for configure.in

# Run a *-config script and pull out the cflags and libs settings
AC_DEFUN([LIB_CONFIG],[
   AC_PATH_PROG([$1], [$2])
   CONFIG_PATH=${$1}
   if test "x$CONFIG_PATH" = "x"; then
      AC_MSG_ERROR([Could not find $2 in PATH; is $3 installed?])
   fi

   $4="$($CONFIG_PATH --cflags) ${$4}"
   $5="$($CONFIG_PATH --libs) ${$5}"
])

# Check for a function; if it doesn't exist, puke
AC_DEFUN([REQUIRE_FUNC], [
   AC_CHECK_FUNCS($1)
   if test $ac_cv_func_$1 = no; then
     AC_MSG_ERROR([Cutlass needs the function $1(), but it cannot be found]);
   fi
])

AC_DEFUN([CHECK_PTHREADS], [
   case "$target" in
      *-*-freebsd* | *-*-openbsd*)
	 pthread_cflags="-D_REENTRANT -D_THREAD_SAFE"
	pthread_lib="-pthread"
      ;;
      *)
         pthread_cflags="-D_REENTRANT"
         pthread_lib="-lpthread"
      ;;
   esac

   LIBS="$pthread_lib $LIBS"
   CFLAGS="$pthread_cflags $CFLAGS"
   CXXFLAGS="$pthread_cflags $CXXFLAGS"

   AC_MSG_CHECKING(for POSIX threads)
   use_pthreads=no
   AC_TRY_LINK([#include <pthread.h>],
      [
      pthread_mutex_t mutex;
      pthread_mutex_init(&mutex, NULL);
      ],
      [use_pthreads=yes],
      [AC_MSG_ERROR("Cutlass requires POSIX threads")]
   );
   AC_MSG_RESULT($pthread_cflags $pthread_lib)
])


AC_DEFUN([PKG_CHECK_MODULES], [
  succeeded=no

  if test -z "$PKG_CONFIG"; then
    AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  fi

  if test "$PKG_CONFIG" = "no" ; then
     echo "*** The pkg-config script could not be found. Make sure it is"
     echo "*** in your path, or set the PKG_CONFIG environment variable"
     echo "*** to the full path to pkg-config."
     echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
  else
     PKG_CONFIG_MIN_VERSION=0.9.0
     if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
        AC_MSG_CHECKING(for $2)

        if $PKG_CONFIG --exists "$2" ; then
            AC_MSG_RESULT(yes)
            succeeded=yes

            AC_MSG_CHECKING($1_CFLAGS)
            $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
            AC_MSG_RESULT($$1_CFLAGS)

            AC_MSG_CHECKING($1_LIBS)
            $1_LIBS=`$PKG_CONFIG --libs "$2"`
            AC_MSG_RESULT($$1_LIBS)
        else
            $1_CFLAGS=""
            $1_LIBS=""
            ## If we have a custom action on failure, don't print errors, but 
            ## do set a variable so people can do so.
            $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
            ifelse([$4], ,echo $$1_PKG_ERRORS,)
        fi

        AC_SUBST($1_CFLAGS)
        AC_SUBST($1_LIBS)
     else
        echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
        echo "*** See http://www.freedesktop.org/software/pkgconfig"
     fi
  fi

  if test $succeeded = yes; then
     ifelse([$3], , :, [$3])
  else
     ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
  fi
])