dnl
dnl AC_VCHAT_GCC_WALL_CHECK
dnl

AC_DEFUN(AC_VCHAT_GCC_WALL_CHECK,
[
	# When running gcc, add "-Wall" to CFLAGS
	AC_MSG_CHECKING(whether to add '-Wall' to CFLAGS)
	if test x$GCC != x ; then
		CFLAGS="-Wall $CFLAGS"
		AC_MSG_RESULT(yes)
	else
		AC_MSG_RESULT(no)
	fi
])

dnl
dnl AC_VCHAT_AAS_CHECK
dnl

AC_DEFUN(AC_VCHAT_AAS_CHECK,
[
	AC_ARG_WITH(aas,   [  --with-aas              use the aas audio library if available [default=yes]], want_aas="$withval", want_aas="yes")

	if test "x$want_aas" = "xyes" ; then
		AC_CHECK_HEADER(aas.h,,want_aas=no)
	fi

	if test "x$want_aas" = "xyes" ; then
		AC_CHECK_LIB(aas,aas_open,,want_aas=no)
	fi
])

dnl
dnl AC_VCHAT_RPLAY_CHECK
dnl

AC_DEFUN(AC_VCHAT_RPLAY_CHECK,
[
	AC_ARG_WITH(rplay, [  --with-rplay            use the rplay audio library if available [default=yes]], want_rplay="$withval", want_rplay="yes")

	if test "x$want_rplay" = "xyes" ; then
		AC_CHECK_HEADER(rplay.h,,want_rplay=no)
	fi

	if test "x$want_rplay" = "xyes" ; then
		AC_CHECK_LIB(rplay, rplay_open,,want_rplay=no)
	fi
])

dnl
dnl AC_VCHAT_AUDIOLIB_CHECK
dnl

AC_DEFUN(AC_VCHAT_AUDIOLIB_CHECK,
[
	AC_MSG_CHECKING(which audio library to use)

	if test "x$want_aas" = "xyes" ; then

		#
		# If rplay lib is also available, prefer aas over rplay
		#

		if test "x$want_rplay" = "xyes" ; then
			want_rplay="no"
			LIBS=`echo $LIBS | sed "s|-lrplay||"`
		fi

		AC_DEFINE(AUDIO_AAS)
		AC_MSG_RESULT(aas)

	elif test "x$want_rplay" = "xyes" ; then

		AC_DEFINE(AUDIO_RPLAY)
		AC_MSG_RESULT(rplay)

	else

		AC_DEFINE(AUDIO_NONE)
		AC_MSG_RESULT(none)

	fi
])

dnl
dnl AC_VCHAT_OSTYPE_CHECK
dnl

AC_DEFUN(AC_VCHAT_OSTYPE_CHECK,
[
	AC_MSG_CHECKING(for appropriate OS_TYPE string)

	case $host_os in
		freebsd2*)	OSTP="BSD2"
				;;

		freebsd3*)	OSTP="BSD3"
				;;

		freebsd4*)	OSTP="BSD4"
				;;

		freebsd5*)	OSTP="BSD5"
				;;

		freebsd*)	OSTP="FBSD"
				;;

		netbsd*)	OSTP="NBSD"
				;;

		openbsd*)	OSTP="OBSD"
				;;

		linux*)		OSTP="LNXE"
				;;

		solaris2*)	OSTP="SOL2"
				;;

		bsdi*)		OSTP="BSDI"
				;;

		next*)		OSTP="NEXT"
				;;

		irix5*)		OSTP="IRX5"
				;;

		irix6*)		OSTP="IRX6"
				;;

		aix*)		OSTP="AIX-"
				;;

		sun*)		OSTP="SUNO"
				;;

		*)		OSTP="UKWN"
				;;
	esac

	AC_MSG_RESULT($OSTP)

	AC_DEFINE_UNQUOTED(OS_TYPE, "${OSTP}",The appropriate operating system type string.)
])

dnl
dnl AC_VCHAT_ODD_ADDR_CHECK
dnl

AC_DEFUN(AC_VCHAT_ODD_ADDR_CHECK,
[
	AC_MSG_CHECKING(for odd address support)

	case $host_os in
		freebsd*)	soa="1"
				;;
		linux*)		soa="1"
				;;
		*)		soa="0"
				;;
	esac

	AC_DEFINE_UNQUOTED(SUPPORT_ODD_ADDRS, ${soa}, Define to 1 if system supports odd addresses.)

	if test "x$soa" = "x1"; then
		AC_MSG_RESULT(yes)
	else
		AC_MSG_RESULT(no)
	fi
])

dnl
dnl AC_VCHAT_VERSION_CHECK
dnl

AC_DEFUN(AC_VCHAT_VERSION_CHECK,
[
	AC_MSG_CHECKING(for version and release date)

	vc_version=`head -1 ./version`
	vc_reldate=`head -2 ./version | tail -1`

	AC_DEFINE_UNQUOTED(VERSION, "$vc_version", Defined to the vchat client version.)
	AC_DEFINE_UNQUOTED(REL_DATE, "$vc_reldate", Defined to the release date of the client.)

	AC_MSG_RESULT($vc_version / $vc_reldate)
])