dnl configure.in. To be processed by autoconf. 

dnl include pvm++ support

builtin(include, pvm++.m4)

dnl test for sanity of distribution

AC_INIT(pvm++/class.cc)

dnl automake init. Set package name and version number

AM_INIT_AUTOMAKE(pvm++, 0.6.0)
     
dnl Set library version number
dnl (not to be confused with package version number)

dnl version-number is CURRENT:REVISION:AGE

dnl Quote from the libtool-info-pages:
dnl CURRENT
dnl      The most recent interface number that this library implements.
dnl 
dnl REVISION
dnl      The implementation number of the CURRENT interface.
dnl 
dnl AGE
dnl      The difference between the oldest and newest interfaces that this
dnl      library implements.  In other words, the library implements all the
dnl      interface numbers in the range from number `CURRENT - AGE' to
dnl      `CURRENT'.

VERSION_INFO=1:0:0
AC_SUBST(VERSION_INFO)

dnl Checks for programs.

AC_PROG_CXX
AC_LANG_CPLUSPLUS
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AM_PROG_LIBTOOL

AC_FIND_PVM

dnl Check for the type of the FD-Set Arguments to select

FD_SET_TYPE=

AC_MSG_CHECKING([type for 2nd, 3rd and 4th parameter to select])

for type in fd_set int; do
  AC_TRY_COMPILE([
    #include <sys/time.h>
    #include <sys/types.h>
    #include <unistd.h>
  ],[
    fd_set Test;
    select( 0, ($type*) &Test, NULL, NULL, NULL ); 
  ],[
    FD_SET_TYPE=$type
    break 
  ])
done

if test x"$FD_SET_TYPE" = x; then
  AC_MSG_RESULT(not found)
  AC_MSG_ERROR(Fatal error. Please submit a bug report.)
fi

AC_MSG_RESULT(($FD_SET_TYPE*))

dnl Set the CXXFLAGS and LDFLAGS for pvm++.

CXXFLAGS="$CXXFLAGS $PVM_CFLAGS -I\$(top_srcdir)"
CXXFLAGS="$CXXFLAGS -DFD_SET_TYPE=\"$FD_SET_TYPE\""

PROG_LDFLAGS="$PVM_LDFLAGS \$(top_builddir)/pvm++/libpvm++.la"
AC_SUBST(PROG_LDFLAGS)

dnl set all warning flags for gcc

if test "x$GXX" = "xyes"; then
  case " $CXXFLAGS " in
  *[\ \	]-Wall[\ \	]*) ;;
  *) CXXFLAGS="$CXXFLAGS -Wall -Wunused -Wmissing-prototypes -Wmissing-declarations" ;;
  esac
fi

dnl Outputs all files.

AC_OUTPUT([\
	Makefile \
	pvm++/Makefile \
	examples/Makefile \
	examples/forkjoin/Makefile \
	examples/mult/Makefile \
	examples/talk/Makefile \
	doc/Makefile \
	tests/Makefile \
	])