dnl acinclude.m4  -  macros used to create configuration script
dnl
dnl Copyright (C) 1996-2003 Gero Kuhlmann
dnl
dnl $Id: acinclude.m4,v 1.4 2003/03/09 00:43:09 gkminix Exp $
dnl
dnl
dnl
dnl Define a macro which can be used to run an assembler or compiler and
dnl act on its return code
dnl
dnl NB_CHECK_COMP(progname, programcode[, exec-if-true[, exec-if-false]])
dnl
AC_DEFUN([NB_CHECK_COMP],
[cat > conftest.test <<EOF
[$2]
EOF
if eval [$1] conftest.test >&5 2>&5; then
  m4_ifvaln([$3], [rm -rf conftest*
  $3
])dnl
  m4_ifvaln([$4], [else
  rm -rf conftest*
  $4
])dnl
fi
rm -f conftest*]
)dnl

dnl
dnl Check if the C compiler understands a specific command line option
dnl
dnl NB_CHECK_CC_ARG(args[, exec-if-true[, exec-if-false]])
dnl
AC_DEFUN([NB_CHECK_CC_ARG],
[AC_REQUIRE([AC_PROG_CC])dnl
AC_CACHE_CHECK(whether ${CC-cc} accepts -[$1], ac_cv_prog_cc_[$1], [
    echo 'void f(){}' > conftest.c
    if test -z "`${CC-cc} -[$1] -c conftest.c 2>&1`"; then
      ac_cv_prog_cc_[$1]=yes
      m4_ifvaln([$2], [$2])dnl
    else
      ac_cv_prog_cc_[$1]=no
      m4_ifvaln([$3], [$3])dnl
    fi
  ])
rm -f conftest*])