AC_INIT
AC_CONFIG_SRCDIR([src/libnd.h])

AC_SUBST(version_major)
AC_SUBST(version_minor)
version_major=0
version_minor=9

AC_DEFINE_UNQUOTED(VERSION_MAJOR, "$version_major", [Major package version])
AC_DEFINE_UNQUOTED(VERSION_MINOR, "$version_minor", [Minor package version])
AM_INIT_AUTOMAKE(libnetdude, "$version_major.$version_minor")
AM_CONFIG_HEADER([config.h])

dnl Commands for funkier shtool output:
BLD_ON=`./shtool echo -n -e %B`
BLD_OFF=`./shtool echo -n -e %b`

AC_PROG_CC
AC_PROG_MAKE_SET

AC_LIBLTDL_CONVENIENCE
AC_CONFIG_SUBDIRS(libltdl)

AC_LIBTOOL_DLOPEN
AM_PROG_LIBTOOL
AC_DEFINE(LT_NON_POSIX_NAMESPACE, 1, [For libtool -- what exactly was this for again???])

AC_CANONICAL_HOST
AC_C_BIGENDIAN

AM_CONDITIONAL(SOLARIS_HOST, false)
AM_CONDITIONAL(LINUX_HOST, false)
AM_CONDITIONAL(BSD_HOST, false)
AM_CONDITIONAL(APPLE_HOST, false)

case "$host" in
  *-solaris*)
    AC_DEFINE(SOLARIS_HOST, 1, [Whether this is a Solaris host])
    AM_CONDITIONAL(SOLARIS_HOST, true)
    ;;
  *-linux*)
    AC_DEFINE(LINUX_HOST, 1, [Whether this is a Linux host])
    AM_CONDITIONAL(LINUX_HOST, true)
    ;;
  *bsd*)
    AC_DEFINE(BSD_HOST, 1, [Whether this is a BSD host])
    AM_CONDITIONAL(BSD_HOST, true)
    ;;
  *-apple*)
    AC_DEFINE(BSD_HOST, 1, [Whether this is a BSD host])
    AM_CONDITIONAL(BSD_HOST, true)
    AC_DEFINE(APPLE_HOST, 1, [Whether this is an Apple host])
    AM_CONDITIONAL(APPLE_HOST, true)
    ;;
esac

dnl ##################################################
dnl # Set PACKAGE_LIB_DIR in config.h.
dnl ##################################################
if test "x${libdir}" = 'x${exec_prefix}/lib'; then
  if test "x${exec_prefix}" = "xNONE"; then
    if test "x${prefix}" = "xNONE"; then
      PACKAGE_LIB_DIR="${ac_default_prefix}/lib"
    else
      PACKAGE_LIB_DIR="${prefix}/lib"
    fi
  else
    PACKAGE_LIB_DIR=`eval eval eval eval "echo $exec_prefix"`
    PACKAGE_LIB_DIR="$PACKAGE_LIB_DIR/lib"
  fi
else
  PACKAGE_LIB_DIR=`eval eval eval eval "echo $libdir"`
fi
AC_DEFINE_UNQUOTED(PACKAGE_LIB_DIR, "$PACKAGE_LIB_DIR", [The library prefix of the package])
AC_SUBST(PACKAGE_LIB_DIR)

dnl ##################################################
dnl # Set PACKAGE_LOCALE_DIR in config.h.
dnl ##################################################
if test "x${prefix}" = "xNONE"; then
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${ac_default_prefix}/${DATADIRNAME}/locale", [The locale dir of the package])
else
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${prefix}/${DATADIRNAME}/locale", [The locale dir of the package])
fi

dnl ##################################################
dnl # Set PACKAGE_DATA_DIR in config.h.
dnl ##################################################
if test "x${datadir}" = 'x${prefix}/share'; then
  if test "x${prefix}" = "xNONE"; then
    PACKAGE_DATA_DIR="${ac_default_prefix}/share/${PACKAGE}"
  else
    PACKAGE_DATA_DIR="${prefix}/share/${PACKAGE}"
  fi
else
  PACKAGE_DATA_DIR="${datadir}/${PACKAGE}"
fi
AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "$PACKAGE_DATA_DIR", [The data dir of the package])
AC_SUBST(PACKAGE_DATA_DIR)

dnl ##################################################
dnl # Set PACKAGE_SOURCE_DIR in config.h.
dnl ##################################################
packagesrcdir=`cd $srcdir && pwd`
AC_DEFINE_UNQUOTED(PACKAGE_SOURCE_DIR, "${packagesrcdir}", [The source dir of the package])

dnl ##################################################
dnl # Set PACKAGE_INCLUDE_DIR in config.h
dnl ##################################################
if test "x${includedir}" = 'x${prefix}/include'; then
  if test "x${prefix}" = "xNONE"; then
    PACKAGE_INCLUDE_DIR="${ac_default_prefix}/include"
  else
    PACKAGE_INCLUDE_DIR="${prefix}/include"
  fi
else
  PACKAGE_INCLUDE_DIR=`eval eval eval eval "echo $includedir"`
fi
AC_DEFINE_UNQUOTED(PACKAGE_INCLUDE_DIR, "$PACKAGE_INCLUDE_DIR", [The header dir being used])
AC_SUBST(PACKAGE_INCLUDE_DIR)


dnl ##################################################
dnl # Check for Glib.
dnl ##################################################
AC_ARG_WITH(glib,
            AC_HELP_STRING([--with-glib=DIR], [Use glib in <DIR>]),
            [CFLAGS="$CFLAGS -I$withval/include"
            LIBS="-L$withval/lib $LIBS"])

AC_PATH_GENERIC(glib,, [
    AC_SUBST(glib_libs)
    AC_SUBST(glib_cflags)],
    AC_MSG_ERROR(Cannot find glib: Is glib-config in path?))
glib_libs=`glib-config --libs`
glib_cflags=`glib-config --cflags`


dnl ##################################################
dnl # Check for pcapnav.
dnl ##################################################
AC_ARG_WITH(pcapnav-config,
    AC_HELP_STRING([--with-pcapnav-config=FILE], [Use given pcapnav-config]),
    [ pcncfg="$withval" ],
    [ AC_PATH_GENERIC(pcapnav,,
          pcncfg="pcapnav-config",
          AC_MSG_ERROR(Cannot find libpcapnav: Is pcapnav-config in path?)) ])

pcapnav_libs=`$pcncfg --libs`
pcapnav_cflags=`$pcncfg --cflags`
AC_SUBST(pcapnav_libs)
AC_SUBST(pcapnav_cflags)

dnl ##################################################
dnl # Check for tcpdump.
dnl ##################################################

AC_ARG_WITH(tcpdump,
            AC_HELP_STRING([--with-tcpdump=PATH], [Path to tcpdump binary]),
	    td=$withval,
	    td="no")

if test ! -x $td; then
  AC_PATH_PROG(td, tcpdump, "no",[$PATH:/usr/sbin:/sbin])
  if test "$td" = "no"; then cat <<EOF;
------------------------------------------------------
ERROR: Could not find tcpdump on this system. If you
       have it installed in some unusual place, try
       passing the --with-tcpdump option.
------------------------------------------------------
EOF
  fi
else
  AC_MSG_NOTICE([Using tcpdump in $td.])
fi

AC_DEFINE_UNQUOTED(TCPDUMP, "$td", [The tcpdump binary initially used])

dnl ##################################################
dnl # Check for libmagic.
dnl ##################################################
magic=yes
AC_CHECK_HEADERS([magic.h],,magic=no)
AC_CHECK_LIB(magic, magic_open,,magic=no)

if test "x$magic" = xyes; then
   AC_DEFINE(USE_LIBMAGIC, 1, [Whether we can use libmagic])
fi 

##################################################
# Check for gtk-doc.
##################################################

AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])

if test "x$with_html_dir" = "x" ; then
  HTML_DIR='${datadir}/gtk-doc/html'
else
  HTML_DIR=$with_html_dir
fi

AC_SUBST(HTML_DIR)

AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)

gtk_doc_min_version_maj=0
gtk_doc_min_version_min=6

if $GTKDOC ; then 
    gtk_doc_version=`gtkdoc-mkdb --version`
    AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version_maj.$gtk_doc_min_version_min])
    if perl <<EOF ; then
      exit (("$gtk_doc_version" =~ /^(\d+)\.(\d+)$/ &&
            (("\$1" > "$gtk_doc_min_version_maj") ||
	     (("\$1" == "$gtk_doc_min_version_maj") &&
	      ("\$2" >= "$gtk_doc_min_version_min")))) ? 0 : 1);
EOF
      AC_MSG_RESULT(yes)
   else
      AC_MSG_RESULT(no)
      GTKDOC=false
   fi
fi

dnl Let people disable the gtk-doc stuff.
AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)

if test x$enable_gtk_doc = xauto ; then
  if test x$GTKDOC = xtrue ; then
    enable_gtk_doc=yes
  else
    enable_gtk_doc=no 
  fi
fi

AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)


dnl ##################################################
dnl # Debugging enable/disable switch
dnl ##################################################
AC_ARG_ENABLE(debugging,
	      AC_HELP_STRING([--enable-debugging], [Use debugging macros to produce helpful output (disabled by default)]),
	      debugging="yes",
	      debugging="no")

if test x$debugging = xyes; then
  AC_DEFINE_UNQUOTED(LIBND_DEBUG, 1, [Enable debugging output])
fi

AC_CONFIG_FILES([
Makefile
src/Makefile
tools/Makefile
tools/lndtool.c
protocols/Makefile
protocols/arp/Makefile
protocols/ether/Makefile
protocols/fddi/Makefile
protocols/802.11/Makefile
protocols/icmp/Makefile
protocols/ip/Makefile
protocols/linux-sll/Makefile
protocols/snap/Makefile
protocols/tcp/Makefile
protocols/udp/Makefile
plugins/Makefile
plugins/ChecksumFix/Makefile
plugins/BPF-Filter/Makefile
test/Makefile
docs/Makefile
])
AC_OUTPUT

dnl ##################################################
dnl # Print summary
dnl ##################################################

echo
echo "         "${BLD_ON}"libnetdude Configuration Summary"${BLD_OFF}
echo "===================================================="
echo

echo "  libpcapnav configuration: "${BLD_ON}"$pcncfg"${BLD_OFF}
echo "  Debugging enabled:        "${BLD_ON}"$debugging"${BLD_OFF}
echo
echo "  Setup finished. Now run:"
echo
echo "  $ "${BLD_ON}"make"${BLD_OFF}
echo "  # "${BLD_ON}"make install"${BLD_OFF}
echo
echo "  (or use "${BLD_ON}"gmake"${BLD_OFF}" when make on your platform isn't GNU make)"
echo