AC_INIT(libgnetwork/gnetwork.h)

AC_PREREQ(2.53)

AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(libgnetwork, 0.0.9)

AM_MAINTAINER_MODE


##############################
# Standard Junk
##############################

AC_PROG_INTLTOOL([0.29])
AC_ISC_POSIX
AC_PROG_CC
AC_STDC_HEADERS
AM_PROG_LIBTOOL


# ############################
# Versioning
# ############################

# Version: 0.0.9
GNETWORK_MAJOR_VERSION=0
GNETWORK_MINOR_VERSION=0
GNETWORK_MICRO_VERSION=9

AC_DEFINE_UNQUOTED(GNETWORK_MAJOR_VERSION, $GNETWORK_MAJOR_VERSION,
		   [Define to the GNetwork major version])
AC_DEFINE_UNQUOTED(GNETWORK_MINOR_VERSION, $GNETWORK_MINOR_VERSION,
		   [Define to the GNetwork minor version])
AC_DEFINE_UNQUOTED(GNETWORK_MICRO_VERSION, $GNETWORK_MICRO_VERSION,
		   [Define to the GNetwork micro version])

# libtool versioning
# Version Format:
#	"LT_CURENT:LT_REVISION:LT_AGE"
# For Bugfix releases:
#	LT_REVISION++
# For api changes (ABI comptatible):
#	LT_CURRENT++
#	LT_REVISION = 0
#	LT_AGE++
# For binary incompatible changes:
#	LT_CURRENT++
#	LT_REVISION = 0
#	LT_AGE = 0
LT_CURRENT=0
LT_REVISION=9
LT_AGE=0
GNETWORK_LTVERSION=$LT_CURRENT:$LT_REVISION:$LT_AGE
AC_SUBST(GNETWORK_LTVERSION)

GNETWORK_API_VERSION=1.0
GNETWORK_VERSION=$GNETWORK_MAJOR_VERSION.$GNETWORK_MINOR_VERSION.$GNETWORK_MICRO_VERSION

AC_SUBST(GNETWORK_API_VERSION)
AC_SUBST(GNETWORK_VERSION)

VERSION=$GNETWORK_VERSION
PACKAGE=libgnetwork


##############################
# Dependencies
##############################

GLIB_REQUIRED_VERSION=2.3.0
GCONF_REQUIRED_VERSION=1.1.10

PKG_CHECK_MODULES(GNETWORK, glib-2.0 >= $GLIB_REQUIRED_VERSION gthread-2.0 >= $GLIB_REQUIRED_VERSION gobject-2.0 >= $GLIB_REQUIRED_VERSION gconf-2.0 >= $GCONF_REQUIRED_VERSION)

AC_SUBST(GNETWORK_CFLAGS)
AC_SUBST(GNETWORK_LIBS)

AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
AC_PATH_PROG(GLIB_MKENUMS, glib-mkenums)

# GTK+ Test Application

GTK_REQUIRED_VERSION=2.0

build_gtk_demo=false
PKG_CHECK_MODULES(GTK, [gtk+-2.0 >= $GTK_REQUIRED_VERSION], build_gtk_demo=true, \
		  AC_MSG_WARN([GTK+ >= 2.0 not found. Not building GTK+ demo.]))
AM_CONDITIONAL(BUILD_GTK_DEMO, $build_gtk_demo)


##############################
# Compile Flags
##############################

GNOME_COMPILE_WARNINGS(maximum)

# Add -Wno-strict-aliasing to CFLAGS.
if test "$GCC" = "yes"; then
	for option in -Wno-strict-aliasing; do
		SAVE_CFLAGS="$CFLAGS"
		CFLAGS="$GNETWORK_CFLAGS $option $CFLAGS"
		AC_MSG_CHECKING([whether gcc understands $option])
		AC_TRY_COMPILE([], [],
			has_option=yes,
			has_option=no,)
		CFLAGS="$SAVE_CFLAGS"
		if test $has_option = yes; then
		  WARN_CFLAGS="$WARN_CFLAGS $option"
		fi
		AC_MSG_RESULT($has_option)
		unset has_option
		unset SAVE_CFLAGS
	done
	unset option
fi


##############################
# I18n
##############################

GETTEXT_PACKAGE=libgnetwork-$GNETWORK_API_VERSION
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Name of default gettext domain])

ALL_LINGUAS="am az ca cs de es fr hr ja ml ms nl no pl pt pt_BR sr sr@Latn sv zh_CN"
AM_GLIB_GNU_GETTEXT


##############################
# SSL Support.
# OpenSSL Stolen from Evolution. :-)
##############################

_USE_SSL=

# these 2 enable's are inverses of each other
AC_ARG_ENABLE(ssl, [  --enable-ssl=[gnutls,openssl,no]      Use SSL to support encryption.], enable_ssl="$enableval", enable_ssl="gnutls")


##############################
# GNU TLS (Default)
##############################

if test "${enable_ssl}" = "gnutls"; then
  AC_CHECK_PROG(GNUTLS, libgnutls-config, true, false)

  gnutls_min_version=1.0

  if $GNUTLS ; then
    AC_MSG_CHECKING([for GNU TLS >= $gnutls_min_version])
    gnutls_version=`libgnutls-config --version`

    IFS="${IFS= 	}"; gnutls_save_IFS="$IFS"; IFS="."
    set $gnutls_version
    for min in $gnutls_min_version ; do
      cur=$1; shift
      if test -z $min ; then break; fi
      if test -z $cur ; then GNUTLS=false; break; fi
      if test $cur -gt $min ; then break ; fi
      if test $cur -lt $min ; then GNUTLS=false; break ; fi
    done
    IFS="$gnutls_save_IFS"

    if $GNUTLS ; then
      AC_MSG_RESULT(yes)
    else
      AC_MSG_RESULT(no)
    fi
  fi

  if $GNUTLS ; then
    AC_DEFINE(USE_GNUTLS, 1, [Using GNU TLS])

    AC_MSG_CHECKING([SSL_CFLAGS])
    gnutls_includes=`libgnutls-config --cflags`
    LIBGNUTLS_CFLAGS="$gnutls_includes"
    AC_MSG_RESULT($LIBGNUTLS_CFLAGS)

    AC_MSG_CHECKING([SSL_LIBS])
    gnutls_libs=`libgnutls-config --libs`
    LIBGNUTLS_LIBS="$gnutls_libs"
    AC_MSG_RESULT($LIBGNUTLS_LIBS)

    SSL_CFLAGS="-D_USE_SSL -D_USE_GNUTLS $gnutls_includes"
    SSL_LIBS="$gnutls_libs"
  else
    SSL_CLFAGS=""
    SSL_LIBS=""
  fi

  SSL_TYPE="GNUTLS"
  
##############################
# OpenSSL
##############################
elif test "${enable_ssl}" = "openssl"; then
  AC_ARG_WITH(openssl_includes, [  --with-openssl-includes=PREFIX     Location of OpenSSL includes.],
	      with_openssl_includes="$withval", with_openssl_includes="/usr/include")
  have_openssl_includes="no"

  if test "x${with_openssl_includes}" != "xno"; then
    CPPFLAGS_save="$CPPFLAGS"

    CPPFLAGS="$CPPFLAGS -I$with_openssl_includes"
    AC_CHECK_HEADERS(openssl/ssl.h)
    CPPFLAGS="$CPPFLAGS_save"
		
    if test "x{$openssl_includes}" != "xno" -a "x{$openssl_includes}" != "x"; then
      have_openssl_includes="yes"

      if test "x${with_openssl_includes}" != "x/usr/include"; then
	OPENSSL_CFLAGS="-I$with_openssl_includes"
      else
	OPENSSL_CFLAGS=""
      fi

      SSL_CFLAGS="-D_USE_SSL -D_USE_OPENSSL $OPENSSL_CFLAGS"
    else
      SSL_CFLAGS=""
    fi
  fi
	
  AC_ARG_WITH(openssl_libs, [  --with-openssl-libs=PREFIX     	Location of OpenSSL libs.],
	      with_openssl_libs="$withval")
  if test "x${with_openssl_libs}" != "xno" -a "x${have_openssl_includes}" != "xno"; then
    LDFLAGS_save="$LDFLAGS"

    case $with_openssl_libs in
      ""|-L*) ;;
      *) with_openssl_libs="-L$with_openssl_libs" ;;
    esac
	
    AC_CHECK_LIB(dl, dlopen, DL_LDFLAGS="-ldl", DL_LDFLAGS="")
    AC_CACHE_CHECK([for OpenSSL libraries], openssl_libs,
    [
      LDFLAGS="$LDFLAGS $with_openssl_libs -lssl -lcrypto $DL_LDFLAGS"
      AC_TRY_LINK_FUNC(SSL_read, openssl_libs="yes", openssl_libs="no")
      LDFLAGS="$LDFLAGS_save"
    ])
    if test "x${openssl_libs}" != "xno"; then
      msg_ssl="yes (OpenSSL)"
      OPENSSL_LDFLAGS="$with_openssl_libs -lssl -lcrypto $DL_LDFLAGS"
    else
      OPENSSL_CFLAGS=""
      OPENSSL_LDFLAGS=""
    fi

    SSL_CFLAGS="$OPENSSL_CFLAGS"
    SSL_LIBS="$OPENSSL_LDFLAGS"
  fi

  SSL_TYPE="OpenSSL"
else
  SSL_CFLAGS=""
  SSL_LIBS=""

  SSL_TYPE="(none)"
fi

AC_SUBST(SSL_CFLAGS)
AC_SUBST(SSL_LIBS)


##############################
# ./configure Flags messings
##############################

cflags_set=${CFLAGS+set}
# find the actual value for $prefix that we'll end up with
REAL_PREFIX=
if test "x$prefix" = "xNONE"; then
  REAL_PREFIX=$ac_default_prefix
else
  REAL_PREFIX=$prefix
fi

# Have to go $sysconfdir->$prefix/etc->/usr/local/etc   
# if you actually know how to code shell then fix this :-)
SYSCONFDIR_TMP="$sysconfdir"
old_prefix=$prefix
prefix=$REAL_PREFIX
EXPANDED_SYSCONFDIR=`eval echo $SYSCONFDIR_TMP`
prefix=$old_prefix
AC_SUBST(EXPANDED_SYSCONFDIR)

dnl Save flags to aclocal
ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"


####################################################
# gtk-doc
####################################################

AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    path to installed docs])

if test "x$with_html_dir" = "x" ; then
  HTML_DIR='${datadir}/gtk-doc/html'
else
  HTML_DIR=$with_html_dir
fi

AC_SUBST(HTML_DIR)

GTK_DOC_CHECK(1.1)


##############################
# GConf
##############################

AC_PATH_PROG(GCONFTOOL, gconftool-2, no)

if test x"$GCONFTOOL" = xno; then
  AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
fi

AM_GCONF_SOURCE_2


##############################
# Flags
##############################

AC_SUBST(CFLAGS)
AC_SUBST(CPPFLAGS)
AC_SUBST(LDFLAGS)


##############################
# Files
##############################

AC_OUTPUT([
Makefile
data/Makefile
data/libgnetwork-1.0.pc
libgnetwork/Makefile
tests/Makefile
doc/Makefile
doc/version.xml
po/Makefile.in
])

echo -en "\n    GNetwork Library Configuration:"
echo -en "\n        SSL Support: $SSL_TYPE\n\n"