CONFIG *= thread
CONFIG += opengl

# needs to be added if the library uses Qt xml parser. Can be removed if not.
macx: QMAKE_LFLAGS += -lqt

contains(HELP, yes) {
  message("options:")
  message("X3DTK_DIR: X3DTK installation directory")
  message("X3DTK_LIB_DIR: X3DTK library binary directory")
  message("X3DTK_INC_DIR: X3DTK include files directory")
  message("QGLVIEWER_DIR: QGLVIEWER installation directory")
  message("QGLVIEWER_LIB_DIR: QGLVIEWER library binary directory")
  message("QGLVIEWER_INC_DIR: QGLVIEWER include files directory")
}

!isEmpty(X3DTK_DIR) {
  INCLUDEPATH *= $$X3DTK_DIR/include
} else {
  !isEmpty(X3DTK_INC_DIR) {
    INCLUDEPATH *= $$X3DTK_INC_DIR
  } else {
    INCLUDEPATH *= ../../include
  }
}  
  

!isEmpty(X3DTK_LIB_DIR) {
  win32 {
    LIBS *= X3DTK100.lib
  } else {
    LIBS *= -L$$X3DTK_LIB_DIR -lX3DTK
  }  
} else {
  !isEmpty(X3DTK_DIR) {
    win32 {
      LIBS *= X3DTK100.lib
    } else {
      LIBS *= -L$$X3DTK_DIR/lib -lX3DTK 
    }
  } else {
    win32 {
      LIBS *= X3DTK100.lib
    } else {
      LIBS *= -L../../lib -lX3DTK 
    }
  } 
}

!isEmpty(QGLVIEWER_DIR) {
  INCLUDEPATH *= $$QGLVIEWER_DIR/include
}

!isEmpty(QGLVIEWER_INC_DIR) {
  INCLUDEPATH *= $$QGLVIEWER_INC_DIR
}

!isEmpty(QGLVIEWER_LIB_DIR) {
  win32 {
    LIBS *= QGLViewer.lib
  } else {
    LIBS *= -L$$QGLVIEWER_LIB_DIR -lQGLViewer
  }  
} else {
  !isEmpty(QGLVIEWER_DIR) {
    win32 {
      LIBS *= QGLViewer.lib
    } else {
      LIBS *= -L$$QGLVIEWER_DIR/lib -lQGLViewer 
    }  
  } else {
    win32 {
      LIBS *= QGLViewer.lib
    } else {
      LIBS *= -lQGLViewer 
    }  
  } 
}

win32:CONFIG += rtti

TARGET = glnormalviewer

HEADERS = \
      GL_NormalRendererGeometry3DVisitor.h \  
      GL_NormalRenderer.h \     
      GL_NormalRendererGroupingVisitor.h \
      GL_NormalRendererStateVariables.h \     
      NormalX3DGLScene.h \
      Viewer.h 
      
SOURCES = \
      GL_NormalRendererGeometry3DVisitor.cpp \  
      GL_NormalRenderer.cpp \     
      GL_NormalRendererGroupingVisitor.cpp \ 
      GL_NormalRendererStateVariables.cpp \              
      NormalX3DGLScene.cpp \
      Viewer.cpp \
      main.cpp