dnl Process this file with autoconf to produce a configure script.
AC_INIT([ePDFView], [0.1.6], [jordi@emma-soft.com])
AC_PREREQ([2.13])
AC_CONFIG_HEADER([config.h])
AC_COPYRIGHT([Copyright (C) 2006 Emma's Software.])
AM_INIT_AUTOMAKE
AM_MAINTAINER_MODE

dnl Parameters.
AC_ARG_ENABLE([debug], [  --enable-debug          turn on debugging [[default=no]]])
if test "x$enable_debug" != "xyes"; then
    DEBUGFLAGS="-DNDEBUG -DG_DISABLE_ASSERT"
else
    DEBUGFLAGS="-DDEBUG"
fi
CFLAGS="$CFLAGS -Wall $DEBUGFLAGS"
CXXFLAGS="$CXXFLAGS -Wall -Wno-long-long $DEBUGFLAGS"

dnl Check for programs.
AC_PROG_CC
AC_PROG_CXX
AC_CHECK_PROG(DOXYGEN, doxygen, yes,)
AM_CONDITIONAL(build_reference, test "x$DOXYGEN" = "xyes")

dnl Check for internationalization.
AM_GNU_GETTEXT

dnl Check for libraries
POPPLER_REQUIRED=0.5.0
GLIB_REQUIRED=2.6.0
GTK2_REQUIRED=2.6.0

PKG_CHECK_MODULES([GLIB], [gthread-2.0 >= $GLIB_REQUIRED])
AC_SUBST([GLIB_CFLAGS])
AC_SUBST([GLIB_LIBS])
PKG_CHECK_MODULES([GTK2], [gtk+-2.0 >= $GTK2_REQUIRED])
AC_SUBST([GTK2_CFLAGS])
AC_SUBST([GTK2_LIBS])
PKG_CHECK_MODULES([POPPLER], [poppler-glib >= $POPPLER_REQUIRED gdk-2.0 >= $GTK2_REQUIRED pango])
AC_SUBST([POPPLER_CFLAGS])
AC_SUBST([POPPLER_LIBS])
dnl Check if we have poppler version 0.5.2 or higher.
PKG_CHECK_EXISTS([poppler-glib >= 0.5.2], [have_poppler_052=yes])
if test "x$have_poppler_052" = "xyes"; then
    AC_DEFINE([HAVE_POPPLER_0_5_2], [1], [Define to 1 if you have Poppler version 0.5.2 or higher.])
fi

EPDFVIEW_PATH_CUPS([CUPS], [have_cups=yes])
AM_CONDITIONAL(cups_printing, test "x$have_cups" = "xyes")
if test "x$have_cups" = "xyes"; then
    AC_SUBST([CUPS_CFLAGS])
    AC_SUBST([CUPS_LIBS])
    AC_DEFINE([HAVE_CUPS], [1], [Define to 1 if you have the CUPS API library.])
fi

dnl CPPUnit library
AM_PATH_CPPUNIT([1.10.2], CPPUNIT="yes")
AM_CONDITIONAL(build_tests, test "x$CPPUNIT" = "xyes" -a "x$enable_debug" = "xyes")

dnl Check for header files.
dnl Check for types.
dnl Check for compiler characteristics.
dnl Check for library functions.
dnl Check for system services.
dnl Output files
AC_CONFIG_FILES([   \
Makefile    \
data/Makefile   \
m4/Makefile \
intl/Makefile   \
po/Makefile.in  \
src/Makefile    \
src/gtk/Makefile    \
tests/Makefile  \
doc/Makefile    \
doc/Doxyfile])
AC_OUTPUT